openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File flst.awk of Package Meta (Revision 5f4ea4e2fade2a021f05356e96204e52)

Currently displaying revision 5f4ea4e2fade2a021f05356e96204e52 , Show latest

#!/bin/awk
BEGIN {
    if (!NAME)
	exit
    ENTRY="^name "NAME
}
$0 ~ ENTRY {
    cnt=0
    flags=0
    files[cnt]=""
    for (;;) {
	if ((getline) <= 0)
	    break
	if ($0 ~ /^[[:blank:]]*$/)
	    break
	if ($0 ~ /^srcfiles/)
	    flags=1
	if ($0 ~ /^docfiles/) {
	    flags=2
	    if (TYPE != flags)
		files[cnt++]="\n%file doc\n%defattr(-,root,root,755)"
	}
	if ($0 ~ /^runfiles/) {
	    flags=4
	    if (TYPE != flags)
		files[cnt++]="\n%file\n%defattr(-,root,root,755)"
	}
	if ($0 ~ /^binfiles/)
	    flags=8
	if ($0 !~ /^[[:blank:]]/)
	    continue
	if (and(TYPE, flags) == 0)
	    continue
	if (sub(/^[[:blank:]]bin\/.*-linux\//, "%{_bindir}/")) {
	    if ($0 ~ /\/man$/)
		continue
	    sub(/-xaw$/, "-xaw3d")
	    files[cnt++]=$0
	    if (sub(/\/musixtex/, "/pdfmusixtex"))
		files[cnt++]=$0
	}
	if (flags == 2)
	    sub(/[[:blank:]]details=[^=]*$/,"")
	if (sub(/^[[:blank:]]RELOC\//, "%{_texmfdistdir}/"))
	    files[cnt++]=$0
	if (sub(/^[[:blank:]]texmf-dist\//, "%{_texmfdistdir}/"))
	    files[cnt++]=$0
	if (sub(/^[[:blank:]]texmf\//, "%{_texmfmaindir}/"))
	    files[cnt++]=$0
	if (sub(/^[[:blank:]]/, "%{_texmfmaindir}/"))
	    files[cnt++]=$0
    }
    for (n=0; n < cnt; n++) {
	print files[n]
    }
    exit
}

Places

File flst.awk of Package Meta (Revision 5f4ea4e2fade2a021f05356e96204e52)

Places