openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File pkg.awk of Package Meta (Revision 7e0324a9c8d7658b634bdb11cd989774)

Currently displaying revision 7e0324a9c8d7658b634bdb11cd989774 , Show latest

#!/bin/awk

function doprovide(path)
{
    for (id in subscripts) {
	if (path ~ subscripts[id]"$") {
	    sub(/^[[:blank:]](RELOC\/)?/, "", path)
	    return path
	}
    }
    return ""
}

BEGIN {
    if (!NAME)
	exit
    ENTRY="^name "NAME
    split(".sty .cls .clo .bbx .cbx .lbx", subscripts)
    idx=0
    scx=0
    cnt=0
    prv=0
    desc[idx]=""
    dependx[cnt]=""
    provide=NAME
    if (sub(/^collection-/, "", provide)) {
	if (provide == "latex")
	    provides[prv++]=provide
	if (provide == "xetex")
	    provides[prv++]=provide
	if (provide == "omega")
	    provides[prv++]=provide
	if (provide == "htmlxml")
	    provides[prv++]=provide
	if (provide == "music")
	    provides[prv++]=provide
	if (provide == "pictures")
	    provides[prv++]=provide
	if (provide == "pstricks")
	    provides[prv++]=provide
	if (provide == "science")
	    provides[prv++]=provide
	if (provide == "metapost")
	    provides[prv++]=provide
	if (provide == "basic") {
	    provides[prv++]=tex
	    provides[prv++]=basic
	}
    } else if (sub(/^collection-lang/, "", provide)) {
	if (provide == "cjk") {
	    provides[prv++]="chinese"
	    provides[prv++]="japanese"
	    provides[prv++]="korean"
	}
	if (provide != "other")
	    provides[prv++]=provide
    } else if (sub(/^scheme-/, "", provide)) {
	if (provide == "context")
	    provides[prv++]=provide
	if (provide == "tetex")
	    provides[prv++]=provide
    } else if (sub(/^texlive-/, "", provide)) {
	if (provide == "dvips")
	    provides[prv++]=provide
    } else
	provides[prv]=""
    tarball[scx++]=NAME".tar.xz"
    noarch="BuildArch: noarch"
    date=""
    license=""
    summary=""
    revision=""
    catversion=""
    isreloc=0
    flags=0
}
$0 ~ ENTRY {
    for (;;) {
	if ((getline) <= 0)
	    break
	if ($0 ~ /^[[:blank:]]*$/)
	    break
	if (sub(/^revision[[:blank:]]+/, ""))
	    revision=$0
	if (sub(/i386-linux[[:blank:]]+files/, "Binaries"))
	    noarch=""
	if (sub(/shortdesc[[:blank:]]+/, "")) {
	    firstchar=toupper(substr($0,1,1))
	    sub(/^[[:lower:]]/, firstchar)
	    sub(/[[:blank:]]+$/,"")
	    summary=$0
	}
	if (sub(/^longdesc[[:blank:]]+/, ""))
	    desc[idx++]=$0
	if ($0 ~ /^depend[[:blank:]]+/) {
	    if ($0 ~ REG)
		continue
	    if (sub(/^depend[[:blank:]]+/, ""))
		dependx[cnt++]=$0
	    continue
	}
	if (SRC && $0 ~ /^docfiles[[:blank:]]+/)
	    tarball[scx++]=NAME".doc.tar.xz"
	if ($0 ~ /^srcfiles[[:blank:]]+/) {
	    continue
	    tarball[scx++]=NAME".source.tar.xz"
	}
	if (sub(/^catalogue-version[[:blank:]]+/, ""))
	    catversion=$0
	if (sub(/^catalogue\-license[[:blank:]]+/, "")) {
	    #
	    # http://www.tex.ac.uk/tex-archive/help/Catalogue/licenses.html
	    # http://www.tex.ac.uk/tex-archive/help/Catalogue/licenses.knuth.html
	    # http://license.opensuse.org/
	    #
	    if ($0 ~ /^apache2/)
		license="Apache-2"
	    else if ($0 ~ /^artistic/) {
		license="Artistic-1 ; GPL-2.0+" # Same License as Perl
		if (TARGET ~ /biber/)
		    license="Artistic-2 ; GPL-1+"
	    } else if ($0 ~ /^artistic2/)
		license="Artistic-2"
	    else if ($0 ~ /^bsd/)	# MIT ???
		license="BSD3c"
	    else if ($0 ~ /^fdl/)
		license="GFDL-1.2"
	    else if ($0 ~ /^pd/)
		license="Public Domain"
	    else if ($0 ~ /^knuth/)
		license="TeX-License"
	    else if ($0 ~ /^gfl/)
		license="LPPL-1.3c with exceptions"
	    else if ($0 ~ /^gfsl/)
		license="LPPL-1.3c with exceptions"
	    else if ($0 ~ /^ofl/)
		license="OFL-1.1"
	    else if ($0 ~ /^lppl1.3/)
		license="LPPL-1.3c"
	    else if ($0 ~ /^lppl1.2/)
		license="LPPL-1.2"
	    else if ($0 ~ /^lppl1/)
		license="LPPL-1"
	    else if ($0 ~ /^lppl/)
		license="LPPL-1"
	    else if ($0 ~ /^gpl3/)
		license="GPL-3+"
	    else if ($0 ~ /^gpl2/)
		license="GPL-2+"
	    else if ($0 ~ /^gpl/) {
		license="GPL-2+"
		if (TARGET ~ /asymptote/)
		    license="LGPL-3.0+"
	    } else if ($0 ~ /^lgpl/)
		license="LGPL-2.1+"
	    else if ($0 ~ /^lgpl3/)
		license="LGPL-3.0+"
	    else if ($0 ~ /^lgpl2\.1/)
		license="LGPL-2.1+"
	    else
		license=toupper($0)
	}
	if (sub(/^catalogue-date[[:blank:]]+/, ""))
	    date=$0
	if ($0 ~ /^[^[:blank:]]/)
	    flags=0
	if (flags > 0 && $0 ~ /^[[:blank:]]RELOC\//)
	    isreloc=1
	if (flags == 4) {
	    provide=doprovide($0)
	    if (provide)
		provides[prv++]=provide
	}
	if ($0 ~ /^runfiles/)
	    flags=4
	if ($0 ~ /^docfiles/)
	    flags=2
    }
    if (PKG)
	print "%package "TARGET
    else
	print "Name: "TARGET
    if (license)
	print "License: " license
    if (summary) {
	print "Summary: " summary
	if (!noarch)
	    print "Group: Productivity/Publishing/TeX/Utilities"
	else if (TARGET ~ /collection-texinfo/)
	    print "Group: Productivity/Publishing/Texinfo"
	else if (TARGET ~ /scheme-/)
	    print "Group: Productivity/Publishing/TeX/Frontends"
	else if (TARGET ~ /collection-(music|omega|xetex|latex|htmlxml|formatsextra|context|basic)/)
	    print "Group: Productivity/Publishing/TeX/Frontends"
	else if (TARGET ~ /collection-fonts/)
	    print "Group: Productivity/Publishing/TeX/Fonts"
	else
	    print "Group: Productivity/Publishing/TeX/Base"
	print "Url: http://www.tug.org/texlive/"
    }
    print "Version: %{texlive_version}"
    if (revision) {
	if (catversion) {
	    if (catversion ~ /^\.[[:digit:]]/)
		catversion = sprintf("0.%s", catversion)
	    if (catversion ~ /^0+\./) {
#		gensub(/^0+\.(.*)/, "\\1", "g", catversion)
		catversion = sprintf("0.%s", catversion)
	    }
	    print "Release: %{texlive_release}." catversion ".svn" revision
	} else
	    print "Release: %{texlive_release}.svn" revision
    }
    for (n=0; n < cnt; n++) {
	if (noarch && dependx[n] ~ /.*-bin$/)
	    print "Requires(prereq): texlive-" dependx[n] " = %{texlive_version}"
	else
	    print "Requires: texlive-" dependx[n] " = %{texlive_version}" 
    }
    if (prv) {
	req=0
	requires[req]=""
	for (n=0; n < prv; n++) {
	    path=provides[n]
	    sub(".*/", "", provides[n])
	    print "Provides: tex("provides[n]")"
	    if (provides[n] !~ /.*\.(sty|cls)$/)
		continue
	    targrep=sprintf("tar OxfJ other/%s %s|grep -E '\\\\(RequirePackage|LoadClass)'", tarball[0], path)
	    while ((targrep | getline line) > 0) {
		if (sub(/\\RequirePackage/, "", line)) {
		    gsub(/[{}]/,"",line)
		    gsub(/,[[:blank:]]*/, " ", line)
		    split(line, styles)
		    for (l in styles)
			requires[req++]=styles[l]".sty"
		    continue
		}
		if (sub(/\\LoadClass/, "", line)) {
		    gsub(/[{}]/,"",line)
		    gsub(/,[[:blank:]]*/, " ", line)
		    split(line, classes)
		    for (l in classes)
			requires[req++]=classes[l]".cls"
		    continue
		}
	    }
	    close(targrep)
	}
	for (n=0; n < req; n++) {
	    self=0
	    for (l=0; l < prv; l++) {
		if (provides[l] == requires[n]) {
		    self=1
		    break
	}
	    }
	    if (!self)
		print "Requires: tex("requires[n]")"
	}
    }
    if (SRC)
	for (n=0; n < scx; n++)
	    print "Source" n ": " SRC "/" tarball[n]
    if (!PKG)
	print "@@PATCHES@@"
    if (noarch)
	print noarch
    else
	print "Prefix: /usr/bin"
    if (!PKG)
	print "@@MACROS@@"
    if (PKG)
	print "\n%description "TARGET
    else
	print "\n%description"
    if (desc[0]) {
	n=0
	for (n=0; n < idx; n++ )
	    print desc[n]
    } else if (!noarch)
	print summary
    else
	print "The " TARGET " package"
    if (date) {
	date=sprintf("date --date='%s' --utc +'%%Y-%%m-%%d %%T %%z' ", date)
	date | getline line
	close(date)
	date=line
	print "\ndate: " date
    }
    for (n=1; n < scx; n++) {
	if (tarball[n] !~ /.*\.doc\.tar\.xz/)
	    continue
	print "\n%package doc"
	print "Summary: Documentation for " NAME
	print "Version: %{texlive_version}"
	if (revision) {
	    if (catversion) {
		if (catversion ~ /.[[:digit:]]+/)
		    catversion = "0" catversion
		print "Release: %{texlive_release}." catversion ".svn" revision
	    } else
		print "Release: %{texlive_release}.svn" revision
	}
	print "BuildArch: noarch"
	print "\n%description doc"
	print "Documentation for texlive-" NAME
    }
    if (!PKG) {
	print "@@SOURCE@@"
	for (n=0; n < scx; n++) {
	    if (isreloc)
		print "    tar --use-compress-program=xz -xf %{S:"n"} -C %{buildroot}%{_datadir}/texlive/texmf-dist"
	    else
		print "    tar --use-compress-program=xz -xf %{S:"n"} -C %{buildroot}%{_datadir}/texlive"
	}
    }
    exit
}

Places

File pkg.awk of Package Meta (Revision 7e0324a9c8d7658b634bdb11cd989774)

Places