openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package MediaInfo (Revision 79349c9bcb97bd5301a39ec80024cff7)

Currently displaying revision 79349c9bcb97bd5301a39ec80024cff7 , Show latest

# $Id$
# Maintainer: MediaArea.net SARL <info@mediaarea.net>
# Contributor: hydro <hydro@freenet.de>

pkgname=('mediainfo' 'mediainfo-gui')
pkgver=24.04.20240523
pkgrel=1
pkgdesc="supplies technical and tag information about a video or audio file"
url="http://mediaarea.net"
license=('BSD-2-Clause')
source=(${pkgname}_${pkgver}.orig.tar.xz)
md5sums=('2f294843c78a5c64e6eaa3ecaad8e6ce')
arch=('i686' 'x86_64')

depends=('libzen>=0.4.41' 'libmediainfo>=24.04' 'wxwidgets-gtk3' 'webkit2gtk' 'bubblewrap' 'libsm' 'desktop-file-utils')

prepare() {
    cd "${srcdir}"/MediaInfo/Project/GNU/CLI
    sh ./autogen.sh
    ./configure --prefix=/usr

cd "${srcdir}"/MediaInfo/Project/GNU/GUI
    sh ./autogen.sh
    ./configure --prefix=/usr --with-wx-config=/usr/bin/wx-config
}

build() {
    cd "${srcdir}"/MediaInfo/Project/GNU/CLI
    make

cd "${srcdir}"/MediaInfo/Project/GNU/GUI
    make
}

package_mediainfo() {
    pkgdesc="${pkgdesc} (CLI)"
    depends=('libmediainfo')

cd "${srcdir}"/MediaInfo/Project/GNU/CLI
    make DESTDIR="${pkgdir}" install
}

package_mediainfo-gui() {
    pkgdesc="${pkgdesc} (GUI)"
    depends=('libmediainfo' 'wxwidgets-gtk3' 'webkit2gtk' 'bubblewrap' 'libsm' 'desktop-file-utils')

cd "${srcdir}"/MediaInfo/Project/GNU/GUI
    make DESTDIR="${pkgdir}" install
}

Places

File PKGBUILD of Package MediaInfo (Revision 79349c9bcb97bd5301a39ec80024cff7)

Places