File PKGBUILD of Package linphone-desktop

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package linphone-desktop (Revision 55089946fd927d4e5abcc587ec754063)

Currently displaying revision 55089946fd927d4e5abcc587ec754063 , Show latest

# Fix for error: bsdtar: Failed to set default locale
# LANG=en_US.UTF-8 # not available, use C or POSIX
LANG=C
LC_ALL=${LANG}
# Get some information about the machine we are building on:
_numberOfProcessorsOnMachine=$(nproc)
_wantedJobs=$(echo "1.1*${_numberOfProcessorsOnMachine}" | bc -l)
_jobsIget=$(echo ${_wantedJobs} | awk '{print int($1+0.5)}')
_TOTAL_DISK=$(df -h --total | awk 'END{print $2}')
_FREEMEM=$(free --mega)
_TOTAL_MEM=$(free --total --mega | xargs | awk '{print $19"MB"}')
_TOTAL_RAM=$(free --total --mega | xargs | awk '{print $8"MB"}')
_TOTAL_SWAP=$(free --total --mega | xargs | awk '{print $15"MB"}')
pkgname=linphone-desktop
pkgver=5.2.0
pkgrel=4
pkgdesc='A free VoIP and video softphone based on the SIP protocol'
arch=(x86_64)
url='http://linphone.org'
license=(GPL)
depends=('qt5-base' 'qt5-multimedia' 'qt5-graphicaleffects' 'qt5-quickcontrols' 'qt5-svg' 'qt5-speech' 'libxcrypt-compat' 'v4l-utils' 'glew')
optdepends=('linphone-contacts-vcard-csv-import-export: linphone contacts vCard CSV avatar import export')
makedepends=('coreutils' 'procps-ng' 'bc' 'git' 'gendesk' 'cmake' 'meson' 'yasm' 'nasm' 'doxygen' 'perl' 'python-pystache' 'python-six' 'libpulse' 'qt5-base' 'qt5-declarative' 'qt5-quickcontrols2' 'qt5-svg' 'qt5-tools')
# git download has to go into _service file
# modified to save also .git folder
# which is by default removed by download service:
# source=("${pkgname}-${pkgver}.tar.xz::git+https://github.com/BelledonneCommunications/linphone-desktop.git#commit=abcdefa"
source=("${pkgname}-${pkgver}.tar.xz"
        "linphone.png::https://gitlab.linphone.org/BC/public/linphone-desktop/-/raw/8dfd384e3df08b200c8eb382b740da6839961bf0/linphone-app/assets/icons/hicolor/128x128/apps/icon.png"
        )
sha512sums=('SKIP'
            'd6495cdc022b1e4c92b3641cb70347e7e6b6ef47599004de729e908b4876a12540713ab54b588611c99c8025fb9b33e3392573c85c13f72cdaee8bcf7a73d65d'
)
options=()
_uploaddir=/usr/src/packages/SOURCES
_sourcedir=/usr/src/packages/BUILD/${pkgname}/src/${pkgname}-${pkgver}
# srcdir is already defined as
# ${srcdir}=/usr/src/packages/BUILD/${pkgname}/src
_builddir=/usr/src/packages/BUILD/${pkgname}/build
_pkgdir=/usr/src/packages/BUILD/${pkgname}/pkg/${pkgname}

build() {
  echo "--- Machine data we are building on ---"
  echo "Total disk: $_TOTAL_DISK"
  echo "Output of free -h:"
  echo "$_FREEMEM"
  echo "Total memory: $_TOTAL_MEM"
  echo "Total RAM: $_TOTAL_RAM"
  echo "Total SWAP: $_TOTAL_SWAP"
  echo "_numberOfProcessorsOnMachine=$_numberOfProcessorsOnMachine"
  echo "_wantedJobs=$_wantedJobs"
  echo "_jobsIget=$_jobsIget"
  echo "--- End machine data we are building on ---"
  cd "$srcdir/${pkgname}-${pkgver}"

# git download has to go into _service file:
  # git submodule update --init --recursive
  mkdir -p build build/OUTPUT && cd build

# -DCMAKE_BUILD_TYPE=RelWithDebInfo
  # -DCMAKE_BUILD_TYPE=Release
  cmake .. -DCMAKE_BUILD_PARALLEL_LEVEL=${_jobsIget} -DCMAKE_BUILD_TYPE=RelWithDebInfo -DCMAKE_INSTALL_PREFIX=/opt/linphone
  # --config RelWithDebInfo
  # --config Release
  cmake --build . --target install --parallel ${_jobsIget} --config RelWithDebInfo

cd "$srcdir"
  gendesk -f -n \
     --pkgname="$pkgname" \
     --pkgdesc="$pkgdesc" \
     --name=Linphone \
     --genericname="VoIP Client" \
     --categories=Network \
     --icon=linphone.png \
     --exec=/opt/linphone/bin/linphone \
     --terminal=false \
     --startupnotify=true \
     --comment "Linphone"
}

package() {
  mkdir -p "$pkgdir/opt/linphone/"
  
  echo "--- Exchange nowebcamCIF.jpg ---"
  cp -v "${_uploaddir}/static.jpg" "$srcdir/${pkgname}-${pkgver}/build/OUTPUT/share/images/nowebcamCIF.jpg"

# Other programs such as emacs crash if libxml2.so* exists
  # in /opt/linphone/lib so we remove it and 
  # use system libxml2 instead
  rm -vf "$srcdir/${pkgname}-${pkgver}/build/OUTPUT/lib/libxml2.so.2"
  rm -vf "$srcdir/${pkgname}-${pkgver}/build/OUTPUT/lib/libxml2.so"
    
  cp -r "$srcdir/${pkgname}-${pkgver}/build/OUTPUT/." "$pkgdir/opt/linphone/"

mkdir -p "$pkgdir/usr/share/applications/"
  install -Dm644 "$srcdir/linphone-desktop.desktop" "$pkgdir/usr/share/applications/"

mkdir -p "$pkgdir/usr/share/pixmaps/"
  install -Dm644 "$srcdir/linphone.png" "$pkgdir/usr/share/pixmaps/"

# Fix /opt/linphone/bin/linphone not finding its libraries in ../lib/
  # Create linphone-desktop.conf and let ldconfig find those libraries
  mkdir -p "$pkgdir/etc/ld.so.conf.d"
  echo "/opt/linphone/lib" > "$pkgdir/etc/ld.so.conf.d/linphone-desktop.conf"
  chmod 644 "$pkgdir/etc/ld.so.conf.d/linphone-desktop.conf"
}

Places

File PKGBUILD of Package linphone-desktop (Revision 55089946fd927d4e5abcc587ec754063)

Places