openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package linux-px (Revision 0d9730f3a3ef5ef55ca89dc5b60ac48f)

Currently displaying revision 0d9730f3a3ef5ef55ca89dc5b60ac48f , Show latest

pkgbase=linux-px
pkgname=("$pkgbase" "$pkgbase-headers")
pkgver=6.4.6
pkgrel=1
pkgdesc='Linux Px'
_srctag=v$pkgver
url="https://www.kernel.org"
arch=(x86_64)
license=(GPL2)
makedepends=(
  bc cpio gettext git libelf pahole perl python tar xz
  clang llvm lld
)
options=('!strip')
_srcname=linux
source=(
  "$_srcname::git+file://linux?tag=$_srctag"
  'https://github.com/sirlucjan/kernel-patches/raw/709c8/6.4/arch-patches-v6-sep/0001-ZEN-Add-sysctl-and-CONFIG-to-disallow-unprivileged-C.patch'
  'https://github.com/graysky2/kernel_compiler_patch/raw/9d14/more-uarches-for-kernel-5.17%2B.patch'
  'https://github.com/zhmars/cjktty-patches/raw/34f6/v6.x/cjktty-6.4.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/21c90/6.4/bore-eevdf-scheduler-patches-v6/0001-bore-6.4-introduce-BORE-Scheduler-with-EEVDF-patches.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/da26e/6.4/v4l2loopback-patches/0001-media-v4l2-core-add-v4l2loopback.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/53230/6.4/fixes-miscellaneous-v7/0001-fixes-miscellaneous.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/b071e/6.4/maple-lru-patches-v8/0001-mm-6.4-add-maple-tree-and-mglru-fixes.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/dd6eb/6.4/amd-pstate-patches-v3/0001-amd-6.4-merge-changes-from-dev-tree.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/e3f1ba/6.4/lrng-patches/0001-lrng-6.4-introduce-Linux-Random-Number-Generator.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/a3fcc/6.4/vma-patches-v20/0001-vma-6.4-merge-changes-from-dev-tree.patch'
  'https://github.com/sirlucjan/kernel-patches/raw/eae33b/6.4/clang-patches/0001-clang-6.4-add-miscellaneous-fixes-for-clang.patch'
  'optimize_harder_Ofast.patch'
  config         # the main kernel config file
)
b2sums=('SKIP'
        'b694c1f2a53faac5cef46bae1ff09f0cb9afe7fb7f290ee8951e82e2c975b7c4d85854c318a19dcf10156c94d8847feb724c139d068d8666e4f9ae5a5d89bc21'
        '508ff463d936e07e0c3ac2017da12bda52d3db5d98d45fe908f35c4d9fadb253cc9d5c17b8915ec600b5024fcecc2746a04d32096e7ebf691438d4ab8bd067a8'
        '137f469cf6931c2ea64393b808cf7d31497ef361170f624b105fc8920168354fa7ac27dcf5eaa929832ed7fd4a391c65561c7736619c740edb267f4fad50bc58'
        '2679b930ecd145b3a5c6f0e3019dc87be9d000b654db94cfbc0c007faad76e8e14ae9306887869d247bf89c9193fbf36a05d58f7ce23b99bbe72be53cee7b644'
        '38551df6b86fb7c4358fec3c33737a6178588f7363b8105259dbf343cb31b57babff17b4ce180c320c3353eb75a77f45eb1e93316eeb5853d00f8a9cde0e908f'
        'b84ab4a15120bbb84da398130e5492eb4fc983a36347887520656fd1be6d6f1db4606afb80a6a39a789fe051f2c0759e2fb035d461ec9bfd7cffb73bab6502be'
        '5a422643dc93cfe9e451cd225e072013285ea3b8d4ee61912e023fa9b8543b5aa7f6216ab95aebaffafae303a3bf79861ace278563e39130aa51da66f4072bd3'
        '5a8efc3869eff1d8e4b84b62bafcaa73a4a992706e60e5cee09bca4be4c463fedccc97e278d33e3028d36ec3d45d6ac11184713d63aa3a26738bd5481bad8252'
        '7e3a8bde0119af48376f2285c12a606c4bab7f449ea92b107b44fa8ef24e61f62d5a160b97311911cf6c3b981198f10488f5af73626187f87867f966c3d08e87'
        'b7c1f66f938919884f852add098d8547cce47328643216f342fb943f91cebd5674a69313a9c67e70b819410da4a26bac09eb99023e4823cc363b4ffb948e05ef'
        'ef488d9448be3c7b8e9bbac516bcc39b9e084c5d084aa4e7bc10d0c51de0d1390b6754db470262ce78e7186f00cbb9b847ebfdfc5dd4e1b051d1d84fe49cfd6f'
        '1dfb8fcae9e21c4fc437d2d8ea61c7b4ebff9a7e0acdfa2180488916f75c8264c09874f66234c1d61f545b1e19a97c10c8fd507ccdac6274aae11e7ac1eda8e5'
        'c5d75cd5be9879c6335c7599671d6dacd22d568c5c3c23d08a7c3a8c622248a606445c2c53e3ef2ce08748298e1ddbabfd6b2af7fd36f93abad14b6e46a87889')

export KBUILD_BUILD_HOST=archlinux
export KBUILD_BUILD_USER=$pkgbase
export KBUILD_BUILD_TIMESTAMP="$(date -Ru${SOURCE_DATE_EPOCH:+d @$SOURCE_DATE_EPOCH})"

export LLVM=1

_make() {
  test -s version
  make KERNELRELEASE="$(<version)" "$@"
}

prepare() {
  cd $_srcname

echo "Setting version..."
  echo "-$pkgrel" > localversion.10-pkgrel
  echo "${pkgbase#linux}" > localversion.20-pkgname
  make defconfig
  make -s kernelrelease > version
  make mrproper

local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    echo "Applying patch $src..."
    patch -Np1 < "../$src"
  done

echo "Setting config..."
  cp ../config .config
  _make olddefconfig
  diff -u ../config .config || :

echo "Prepared $pkgbase version $(<version)"
}

build() {
  cd $_srcname
  _jobs=$(($(nproc) + 1))
  make -j${_jobs} all
}

_package() {
  pkgdesc="The $pkgdesc kernel and modules"
  depends=(coreutils initramfs kmod)
  optdepends=('wireless-regdb: to set the correct wireless channels of your country'
              'linux-firmware: firmware images needed for some devices')
  provides=(KSMBD-MODULE VIRTUALBOX-GUEST-MODULES WIREGUARD-MODULE)
  replaces=()

cd $_srcname
  local modulesdir="$pkgdir/usr/lib/modules/$(<version)"

echo "Installing boot image..."
  # systemd expects to find the kernel here to allow hibernation
  # https://github.com/systemd/systemd/commit/edda44605f06a41fb86b7ab8128dcf99161d2344
  install -Dm644 "$(_make -s image_name)" "$modulesdir/vmlinuz"

# Used by mkinitcpio to name the kernel
  echo "$pkgbase" | install -Dm644 /dev/stdin "$modulesdir/pkgbase"

echo "Installing modules..."
  ZSTD_CLEVEL=19 _make INSTALL_MOD_PATH="$pkgdir/usr" INSTALL_MOD_STRIP=1 \
    DEPMOD=/doesnt/exist modules_install  # Suppress depmod

# remove build and source links
  rm "$modulesdir"/{source,build}
}

_package-headers() {
  pkgdesc="Headers and scripts for building modules for the $pkgdesc kernel"
  depends=(pahole)

cd $_srcname
  local builddir="$pkgdir/usr/lib/modules/$(<version)/build"

echo "Installing build files..."
  install -Dt "$builddir" -m644 .config Makefile Module.symvers System.map \
    localversion.* version vmlinux
  install -Dt "$builddir/kernel" -m644 kernel/Makefile
  install -Dt "$builddir/arch/x86" -m644 arch/x86/Makefile
  cp -t "$builddir" -a scripts

# required when STACK_VALIDATION is enabled
  install -Dt "$builddir/tools/objtool" tools/objtool/objtool

# required when DEBUG_INFO_BTF_MODULES is enabled
  if [ -f "$builddir/tools/bpf/resolve_btfids" ]; then install -Dt "$builddir/tools/bpf/resolve_btfids" tools/bpf/resolve_btfids/resolve_btfids ; fi

echo "Installing headers..."
  cp -t "$builddir" -a include
  cp -t "$builddir/arch/x86" -a arch/x86/include
  install -Dt "$builddir/arch/x86/kernel" -m644 arch/x86/kernel/asm-offsets.s

install -Dt "$builddir/drivers/md" -m644 drivers/md/*.h
  install -Dt "$builddir/net/mac80211" -m644 net/mac80211/*.h

# https://bugs.archlinux.org/task/13146
  install -Dt "$builddir/drivers/media/i2c" -m644 drivers/media/i2c/msp3400-driver.h

# https://bugs.archlinux.org/task/20402
  install -Dt "$builddir/drivers/media/usb/dvb-usb" -m644 drivers/media/usb/dvb-usb/*.h
  install -Dt "$builddir/drivers/media/dvb-frontends" -m644 drivers/media/dvb-frontends/*.h
  install -Dt "$builddir/drivers/media/tuners" -m644 drivers/media/tuners/*.h

# https://bugs.archlinux.org/task/71392
  install -Dt "$builddir/drivers/iio/common/hid-sensors" -m644 drivers/iio/common/hid-sensors/*.h

echo "Installing KConfig files..."
  find . -name 'Kconfig*' -exec install -Dm644 {} "$builddir/{}" \;

echo "Removing unneeded architectures..."
  local arch
  for arch in "$builddir"/arch/*/; do
    [[ $arch = */x86/ ]] && continue
    echo "Removing $(basename "$arch")"
    rm -r "$arch"
  done

echo "Removing documentation..."
  rm -r "$builddir/Documentation"

echo "Removing broken symlinks..."
  find -L "$builddir" -type l -printf 'Removing %P\n' -delete

echo "Removing loose objects..."
  find "$builddir" -type f -name '*.o' -printf 'Removing %P\n' -delete

echo "Stripping build tools..."
  local file
  while read -rd '' file; do
    case "$(file -Sib "$file")" in
      application/x-sharedlib\;*)      # Libraries (.so)
        strip -v $STRIP_SHARED "$file" ;;
      application/x-archive\;*)        # Libraries (.a)
        strip -v $STRIP_STATIC "$file" ;;
      application/x-executable\;*)     # Binaries
        strip -v $STRIP_BINARIES "$file" ;;
      application/x-pie-executable\;*) # Relocatable binaries
        strip -v $STRIP_SHARED "$file" ;;
    esac
  done < <(find "$builddir" -type f -perm -u+x ! -name vmlinux -print0)

echo "Stripping vmlinux..."
  strip -v $STRIP_STATIC "$builddir/vmlinux"

echo "Adding symlink..."
  mkdir -p "$pkgdir/usr/src"
  ln -sr "$builddir" "$pkgdir/usr/src/$pkgbase"
}

for _p in "${pkgname[@]}"; do
  eval "package_$_p() {
    $(declare -f "_package${_p#$pkgbase}")
    _package${_p#$pkgbase}
  }"
done

# vim:set ts=8 sts=2 sw=2 et:

Places

File PKGBUILD of Package linux-px (Revision 0d9730f3a3ef5ef55ca89dc5b60ac48f)

Places