openSUSE Build Service

Overview Repositories Revisions Requests Users Attributes Meta

File PKGBUILD of Package arc_unpacker (Revision a87b2631ca165eadfb824d6a1762d680)

Currently displaying revision a87b2631ca165eadfb824d6a1762d680 , Show latest

pkgname=arc_unpacker-git
_pkgname=arc_unpacker
pkgver=r2428.456834ec
pkgrel=2
pkgdesc="CLI tool for extracting images and sounds from visual novels."
arch=(x86_64)
url="https://github.com/vn-tools/arc_unpacker"
license=('GPL')
depends=('boost-libs' 'libpng' 'libjpeg-turbo' 'openssl')
optdepends=('libwebp')
makedepends=('boost' 'cmake' mold clang git ninja)
provides=('arc_unpacker-git' 'arc_unpacker')
conflicts=('arc_unpacker')
source=("${_pkgname}-$pkgver.tar"
        'https://raw.githubusercontent.com/catchorg/Catch2/v2.13.8/single_include/catch2/catch.hpp'
        'etc.patch'
        'limits.patch'
        'failing_tests.patch')
sha256sums=('SKIP'
            'f5adf6a4c3237920421d51a11112904084043b015acf2c9058e8f36b92ab2921'
            'e8c02f338aca81df79f6d5c0e302322abd776b2aeb36eb0a57ee93335c0da216'
            '83c82ea28e61b8acb296c33a1a8336c8ac54163b3fa0fd7edd57cd35d72bd671'
            '61244eb2ec5ef7ccfb0a0532d51c256d2e99304098b143522f2bee8da3b8eac0')

prepare() {
  mv "$srcdir/${_pkgname}-$pkgver" "$srcdir/${_pkgname}"

cd "$_pkgname"

# fix sources path
  sed -i "s|\/\.\.\/|\/|g" CMakeLists.txt

# fix etc/ path
  git apply "$srcdir/etc.patch"

# fix includes
  git apply "$srcdir/limits.patch"

# fix tests
  cp "$srcdir/catch.hpp" tests/test_support/catch.h

# disable failing tests
  git apply "$srcdir/failing_tests.patch"
}

build() {
  cd "$_pkgname"
  export CC='clang' CXX='clang++' LDFLAGS="-Wl,-O1,--sort-common,--as-needed,-z,relro,-z,now,-fuse-ld=mold"
  cmake -B build -G Ninja \
        -DCMAKE_INSTALL_PREFIX=/usr/bin/ \
        -DCMAKE_BUILD_TYPE=Release
  ninja -C build -j$(nproc)
}

package() {
  cd "$srcdir/$_pkgname/build"
  install -D -m 755 ${_pkgname} ${pkgdir}/usr/bin/${_pkgname}
  mkdir -p ${pkgdir}/usr/share/${_pkgname}
  cp -r etc ${pkgdir}/usr/share/${_pkgname}
}

Places

File PKGBUILD of Package arc_unpacker (Revision a87b2631ca165eadfb824d6a1762d680)

Places